alter procedure [{databaseOwner}].[{objectQualifier}forum_moderators] (@BoardID int, @StyledNicks bit) as
BEGIN
        select
        ForumID = a.ForumID,
        ForumName = f.Name,
        ModeratorID = a.GroupID,
        ModeratorName = b.Name,
        ModeratorEmail = '',
        ModeratorAvatar = '',
        ModeratorAvatarImage = CAST(0 as bit),
        ModeratorDisplayName = b.Name,
        Style = case(@StyledNicks)
            when 1 then b.Style
            else ''	 end,
        IsGroup=1
    from
        [{databaseOwner}].[{objectQualifier}Forum] f
        INNER JOIN [{databaseOwner}].[{objectQualifier}ForumAccess] a  ON a.ForumID = f.ForumID
        INNER JOIN [{databaseOwner}].[{objectQualifier}Group] b  ON b.GroupID = a.GroupID
        INNER JOIN [{databaseOwner}].[{objectQualifier}AccessMask] c  ON c.AccessMaskID = a.AccessMaskID
    where
        b.BoardID = @BoardID and
		(c.Flags & 64)<>0
    union all
    select
        ForumID = access.ForumID,
        ForumName = f.Name,
        ModeratorID = usr.UserID,
        ModeratorName = usr.Name,
        ModeratorEmail = usr.Email,
        ModeratorAvatar = ISNULL(usr.Avatar, ''),
        ModeratorAvatarImage = CAST((select count(1) from [{databaseOwner}].[{objectQualifier}User] x where x.UserID=usr.UserID and AvatarImage is not null)as bit),
        ModeratorDisplayName = usr.DisplayName,
        Style = case(@StyledNicks)
            when 1 then  usr.UserStyle
            else ''	 end,
        IsGroup=0
    from
        [{databaseOwner}].[{objectQualifier}User] usr
        INNER JOIN (
            select
                UserID				= a.UserID,
                ForumID				= x.ForumID,
                ModeratorAccess		= MAX(ModeratorAccess)
            from
                [{databaseOwner}].[{objectQualifier}vaccessfull] as x
                INNER JOIN [{databaseOwner}].[{objectQualifier}UserGroup] a  on a.UserID=x.UserID
                INNER JOIN [{databaseOwner}].[{objectQualifier}Group] b  on b.GroupID=a.GroupID
            WHERE
                b.BoardID = @BoardID and
		        ModeratorAccess <> 0
            GROUP BY a.UserID, x.ForumID
        ) access ON usr.UserID = access.UserID
        JOIN    [{databaseOwner}].[{objectQualifier}Forum] f
        ON f.ForumID = access.ForumID

        JOIN [{databaseOwner}].[{objectQualifier}Rank] r
        ON r.RankID = usr.RankID
    where
        access.ModeratorAccess<>0
    order by
        IsGroup desc,
        ModeratorName asc
END